Method overloading using namespaces

June 15, 2007 on 5:21 pm | In Actionscript | 3 Comments

It’s too bad that AS3 can’t handle method overloading natively, but there is a way to add at least similar functionality using namespaces. True overloading capability means that the compiler figures out which function to use based on the given arguments. Here you have to help the compiler by giving the appropriate namespace tag:

package
{
    import flash.display.Sprite;

    public class MethodOverloadingExample extends Sprite
    {
        //three methods: three namespaces
        public namespace m1;
        public namespace m2;
        public namespace m3;

        public function MethodOverloadingExample():void
        {
            m1::overloadedMethod(1);
        }

     m1 function overloadedMethod(arg0:int):void
        {
            trace("method 1, args=" + arguments.join("|"));

            var out:Boolean = m2::overloadedMethod(1, 2);
        }

     m2 function overloadedMethod(arg0:int, arg1:int):Boolean
        {
            trace("method 2, args=" + arguments.join("|"));

            var out:Number = m3::overloadedMethod(1, 2, 3);
            return true;
        }

     m3 function overloadedMethod(arg0:int, arg1:int, arg2:int):Number
        {
            trace("method 3, args=" + arguments.join("|"));
            return 3;
        }
    }
}

After instantiating the class the various trace calls print out this:

overloaded method 1, args=1
overloaded method 2, args=1|2
overloaded method 3, args=1|2|3

All methods can have different signatures (number of arguments and return type). Nested ‘overloaded’ method calls are allowed, too. I ran a lot of benchmarks and it turned out that namespaces don’t affect performance at all, so you can use this technique for time-critical situations as well.

If you want to access the methods from outside the class you first have to retrieve the namespace and make the call through it. Somehow you can’t access a namespace directly without getting complains from the compiler, so create a get function first.

//inside the class
public function getNameSpace1():Namespace
{
    return m1;
}
...

//outside the class
var m1:Namespace = obj.getNameSpace1();
obj.m1::overloadedMethod(0);